int LEVELS = 9; //the possible levels, MUST BE A SQUARE

PImage a; //instance of image object

void setup(){
  a = loadImage("convert.jpg"); //load an image into a
  
  size(a.width*int(sqrt(LEVELS)), a.height*int(sqrt(LEVELS))); //set the size of the window based on the size of the image
  background(255); //white background to start
  stroke(0); //going to use black to draw
  
  //loop through every pixel in the image
  for(int y=0; y<a.height; y++){
    for(int x=0; x<a.width; x++){
      //find a number between 0 and the LEVElS constant based on the brightness of a pixel in the image
      int level = int(map(brightness(a.get(x, y)), 0, 255, 0, LEVELS-1));
      
      int count = 0; //var to count levels
      
      //draw dots in a square equal to the number in the level var
      for(int i=0; i<sqrt(LEVELS); i++){
        for(int k=0; k<sqrt(LEVELS); k++){
          if(count>level){
            i = LEVELS; //break from the loops
            k = LEVELS;
          }
          
          point(x*sqrt(LEVELS)+k, y*sqrt(LEVELS)+i); //draw a black pixel
          
          count++; //increment the var so we know which level we are on
        }
      }
    }
  }
}